AC_PREREQ(2.52)
AC_INIT(tasks, 0.13, http://o-hand.com)
AC_CONFIG_SRCDIR(libkoto/koto-task-store.c)
AC_CONFIG_HEADERS([libkoto/config.h])
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)

AM_DISABLE_STATIC
AC_PROG_CPP
AC_PROG_CC
AM_PROG_CC_C_O
AC_PROG_RANLIB

GNOME_COMPILE_WARNINGS

IT_PROG_INTLTOOL([0.33.0])

GETTEXT_PACKAGE=tasks
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext domain name])

AM_GLIB_GNU_GETTEXT

PKG_CHECK_MODULES(GTK, gtk+-2.0)
PKG_CHECK_MODULES(ECAL, libecal-1.2)

# Check for libsexy 0.1.12. Older versions don't support icon-names in the
# entries, so don't work.
PKG_CHECK_MODULES(SEXY, libsexy >= 0.1.12, sexy=yes, sexy=no)
if test $sexy = yes; then
        AC_DEFINE(HAVE_SEXY, 1, [libsexy present])
fi


AC_ARG_ENABLE(gtk,
        AS_HELP_STRING([--enable-gtk],[Build the GTK frontend]),
        ,enable_gtk=yes)
AM_CONDITIONAL(WITH_GTK, test "x$enable_gtk" = "xyes")

omoko=false
AC_ARG_ENABLE(omoko,AS_HELP_STRING([--enable-omoko],[Turn on OpenMoko frontend]),[
                  if test "x$enableval" = "xyes" ; then
                    PKG_CHECK_MODULES(OMOKO,[libmokoui2],
                                      omoko=true,
                                      omoko=false)
                  fi])
AM_CONDITIONAL(WITH_OMOKO, test "x$omoko" = "xtrue")


hildon=false
AC_ARG_ENABLE(hildon,AS_HELP_STRING([--enable-hildon],[Turn on Hildon frontend]),[
                  if test "x$enableval" = "xyes" ; then
                    PKG_CHECK_MODULES(HILDON,
                                      [hildon-1,
                                       dbus-1, 
                                       libhildonmime
                                       ],
                                       hildon=true, hildon=false)
                  fi])
AM_CONDITIONAL(WITH_HILDON, test "x$hildon" = "xtrue")



# This was introduced in GTK+ 2.9
old_cflags=$CFLAGS
CFLAGS=$GTK_CFLAGS
AC_CHECK_DECLS([GDK_WINDOW_TYPE_HINT_COMBO, gtk_style_lookup_color],
               [], [], [#include <gtk/gtk.h>])

AC_CHECK_DECLS([g_date_set_time_t],
               [have_date=yes], [have_date=no], [#include <glib.h>])
AM_CONDITIONAL(HAVE_GDATE_TIME_T, test "x$have_date" = "xyes")

CFLAGS=$old_cflags

# This was introduced in newer libecal
old_cflags=$CFLAGS
CFLAGS=$ECAL_CFLAGS
AC_CHECK_TYPES(ECalComponentId, [], [], [#include <libecal/e-cal.h>])
CFLAGS=$old_cflags

AC_OUTPUT([
Makefile
data/Makefile
data/icons/Makefile
data/icons/16x16/Makefile
data/icons/22x22/Makefile
data/icons/24x24/Makefile
data/icons/26x26/Makefile
data/icons/32x32/Makefile
data/icons/48x48/Makefile
data/icons/64x64/Makefile
data/icons/scalable/Makefile
po/Makefile.in
libkoto/Makefile
src/Makefile
src/gtk/Makefile
src/omoko/Makefile
src/hildon/Makefile
])

if test "x$enable_gtk" = "xyes" ; then
  AC_MSG_NOTICE([Building GTK frontend])
fi

if test "x$omoko" = "xtrue" ; then
  AC_MSG_NOTICE([Building OpenMoko frontend])
fi

if test "x$hildon" = "xtrue" ; then
  AC_MSG_NOTICE([Building Hildon frontend])
fi