AC_PREREQ(2.53)
AC_INIT(dates, 0.0, http://www.openedhand.com/)
AM_INIT_AUTOMAKE()
AC_CONFIG_SRCDIR(libjana/jana-component.c)
AM_CONFIG_HEADER(config.h)
AM_MAINTAINER_MODE

AC_ISC_POSIX
AC_PROG_CC
AC_STDC_HEADERS
AC_PROG_LIBTOOL
IT_PROG_INTLTOOL([0.35.0])

dnl i18n support
GETTEXT_PACKAGE=Dates
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT

PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.12.0)
PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6.0)
PKG_CHECK_MODULES(ECAL, libecal-1.2 >= 1.4.0)

old_cflags=$CFLAGS
CFLAGS=$ECAL_CFLAGS
AC_CHECK_TYPE(ECalComponentId, [], [], [#include <libecal/e-cal.h>])

if test $ac_cv_type_ECalComponentId = yes; then
        AC_DEFINE(HAVE_ECALCOMPONENTID, 1, [Defined if ECalComponentId exists])
fi
CFLAGS=$old_cflags

old_libs=$LIBS
LIBS=$ECAL_LIBS
AC_CHECK_FUNC(e_cal_new_system_memos, AC_DEFINE(HAVE_ECAL_NEW_SYSTEM_MEMOS, 1, [Defined if e_cal_new_system_memos exists]))
LIBS=$old_libs

AC_ARG_WITH([frontend],
	AC_HELP_STRING([--with-frontend],
		[Which frontend to use [[default=none]]]),
		[dates_frontend=$with_frontend])

if test x"$dates_frontend" = x"openmoko"; then
        PKG_CHECK_MODULES(MOKOUI, libmokoui2 >= 0.3)
fi

if test x"$dates_frontend" = x"hildon"; then
        PKG_CHECK_MODULES(HILDON, hildon-1)
fi


AC_ARG_ENABLE([tests],
	AC_HELP_STRING([--enable-tests],
		[Enable building of test applications]),
		[build_tests=tests])

AC_ARG_ENABLE([examples],
	AC_HELP_STRING([--enable-examples],
		[Enable building of example applications]),
		[build_examples=examples])

AC_SUBST([dates_frontend])
AC_SUBST([build_tests])
AC_SUBST([build_examples])

GTK_DOC_CHECK([1.4])

AC_OUTPUT([
Makefile
libjana/Makefile
libjana/libjana.pc
libjana/doc/Makefile
libjana/doc/reference/Makefile
libjana/doc/reference/version.xml
libjana-ecal/Makefile
libjana-ecal/libjana-ecal.pc
libjana-ecal/doc/Makefile
libjana-ecal/doc/reference/Makefile
libjana-ecal/doc/reference/version.xml
libjana-gtk/Makefile
libjana-gtk/libjana-gtk.pc
libjana-gtk/data/Makefile
libjana-gtk/doc/Makefile
libjana-gtk/doc/reference/Makefile
libjana-gtk/doc/reference/version.xml
tests/Makefile
examples/Makefile
openmoko/Makefile
openmoko/data/Makefile
openmoko/libtaku/Makefile
hildon/Makefile
pimlico/Makefile
po/Makefile.in
])